AutoHotKey: Share your Scripts!

[Zet]

No problem bro, I'm glad that I was of help.
By the way, this lead me to think how this would work if the "keypad" keys were to be set on a different place than regular, i.e. 123, qwe, asd, zxc also it's interesting to have the option to have specific mods for the scripts, since I tend to use only the left side alt, ctrl, shift, perhaps using the right ones would be a improve to avoid errors...

[litster]

Also have a hack of a script available from the AHK forums that does volume on my mouse wheel (with Win-key) with an OSD.

 
alaricljs, where can I find your mouse wheel volume script with OSD?  Thanks.

[alaricljs]

I'm using this script for volume in windows 7, I love having the little display.

That's the volume script I'm using modified to the Win+mousewheel and win+0/-/=  (mute/down/up)

alaricljs, where can I find your mouse wheel volume script with OSD?  Thanks.

Ok, so that link above is to the original source at AHK, it requires this library.  And here's my hacked up version that includes win-mousewheel and some other mods.  Note also the Win-o/p/[/]/\ media controls.

Code: [Select]

#NoEnv
#SingleInstance force
SendMode Input

;SetFormat, float, 0.0
;SetBatchLines 10ms
SetBatchLines -1
SetTitleMatchMode 2
DetectHiddenWindows On
CoordMode Mouse, Screen

;COM_Init()
vol_Master := VA_GetMasterVolume()

; The percentage by which to raise or lower the volume each time
vol_Step = 3
; How long to display the volume level bar graphs (in milliseconds)
vol_DisplayTime = 1000
; Transparency of window (0-255)
vol_TransValue = 255
; Transparent background (1/0/true/false) (takes precedence over Window trans,
;   can have only 1 or other, not both)
vol_TransBack = 0
; Bar's background colour
vol_CW = Black  
vol_Width = 200  ; width of bar
vol_Thick = 20   ; thickness of bar
; Bar's screen position
;vol_PosX := A_ScreenWidth - vol_Width - 50
;vol_PosY := A_ScreenHeight - vol_Thick - 100
vol_PosX := 250
vol_PosY := A_ScreenHeight - vol_Thick - 100
; --------------------
; END OF CONFIGURATION
; --------------------
vol_BarOptionsMaster = 1:B ZH%vol_Thick% ZX8 ZY4 W%vol_Width% X%vol_PosX% Y%vol_PosY% CW%vol_CW%
vol_MuteChange = 0
return


;------------ End if initialization section ----------------

;Exit


$Volume_Down::
#WheelDown::
#-::
  If vol_Master > .01
    VA_SetMasterVolume(vol_Master-=vol_Step)
  Gosub, vol_ShowBars

return

$Volume_Up::
#WheelUp::
#=::
  If vol_Master <= 99
    VA_SetMasterVolume(vol_Master+=vol_Step)
  Gosub, vol_ShowBars

return

Volume_Mute::
#MButton::
#0::
  If ( VA_GetMasterMute() ) {
    VA_SetMasterMute(False)
    vol_MuteChange = 1
  } Else {
    VA_SetMasterMute(True)
    vol_MuteChange = 1
  }
  Gosub, vol_ShowBars

return


#o::
  Send {Media_Stop}
return

#p::
  Send {Media_Play_Pause}
return

#[::
  Send {Media_Prev}
return

#]::
  Send {Media_Next}
return


;  Start Winamp or Open Music Folder
;  Player Window
;  M:\

#\::
Launch_Media::
  IfWinExist Player Window
    IfWinExist M:\
      IfWinActive M:\
        WinClose
      else
        WinActivate
    else
      Run M:\
  else
    Run C:\Program Files (x86)\Winamp\winamp.exe

return

;------------------- Start Volume display ------------------------
vol_ShowBars:
; Get volumes in case the user or an external program changed them:
vol_Master := VA_GetMasterVolume()
vol_Mute := VA_GetMasterMute()
if (vol_Mute)
{
  vol_Colour = Red    
  vol_Text = Volume (muted)
}
else
{
  vol_Colour = Green  
  vol_Text = Volume
}
; To prevent the &quot;flashing&quot; effect, only create the bar window if it doesn't already exist:
NED := 0
IfWinNotExist, VolumeOSDxyz
  NED := 1
If (vol_MuteChange or NED)
{
    Progress, %vol_BarOptionsMaster% CB%vol_Colour% CT%vol_Colour%, , %vol_Text%, VolumeOSDxyz
    WinSet, Transparent, %vol_TransValue%, VolumeOSDxyz
    if (vol_TransBack)
      WinSet, TransColor, %vol_CW%, VolumeOSDxyz

  vol_MuteChange = 0
}
Progress, 1:%vol_Master%, , %vol_Text%
SetTimer, vol_BarOff, %vol_DisplayTime%
return


vol_BarOff:
SetTimer, vol_BarOff, off
Progress, 1:Off
return

;-------------------- End Volume display -------------------------



[Zet]

alaricljs I'm loving that idea, I'll use it I think, if somehow I can't get it to work, I'll contact you.
Thanks for the input on this!!!

[litster]

Thanks for the script.  It wouldn't run until also copied and pasted VA.ahk into the same script file.  But it works now.  Now I really want the Topre 87U with the right Windows key because sometimes I use my left hand for mouse.  Yes, I switch mouse left and right to share wrist pain across both hands.

Thanks!

[litster]

I figured it out.  The VA.ahk needs to go to C:\Program Files (x86)\AutoHotkey\Lib.  Thanks.

[Zet]

Woah it took me long to get it to work, what really helped me was adding the VA code into the script that was posted. Then I left it on my desktop and ran it flawlessly

Also, I upgraded to AHK_L and added /lib folder with VA21 and COM_L libs, just for the record.

I'm really liking this scripts and stuff, I'll really look more into it, I love programing

An idea just came up to my head, for a script to block my keyboard and avoid in another way, people using it to unlock my session at work (other programers, really childish ones willing to bother); lets say you want to go lunch and you fear someone saw or knows your password... so they could unlock the session and get on your desktop...
but you could remap all your keys to, lets say 'a' and have the script terminate itself or remaps again properly only when a certain key combination is pressed down

I don't know, there's so many other scripts that could be handy depending situations... ^_^

[Zet]

Ok, so that link above is to the original source at AHK, it requires this library.  And here's my hacked up version that includes win-mousewheel and some other mods.  Note also the Win-o/p/[/]/\ media controls.

Code: [Select]


#NoEnv
#SingleInstance force
SendMode Input

;SetFormat, float, 0.0
;SetBatchLines 10ms
SetBatchLines -1
SetTitleMatchMode 2
DetectHiddenWindows On
CoordMode Mouse, Screen

;COM_Init()
vol_Master := VA_GetMasterVolume()

; The percentage by which to raise or lower the volume each time
vol_Step = 3
; How long to display the volume level bar graphs (in milliseconds)
vol_DisplayTime = 1000
; Transparency of window (0-255)
vol_TransValue = 255
; Transparent background (1/0/true/false) (takes precedence over Window trans,
;   can have only 1 or other, not both)
vol_TransBack = 0
; Bar's background colour
vol_CW = Black  
vol_Width = 200  ; width of bar
vol_Thick = 20   ; thickness of bar
; Bar's screen position
;vol_PosX := A_ScreenWidth - vol_Width - 50
;vol_PosY := A_ScreenHeight - vol_Thick - 100
vol_PosX := 250
vol_PosY := A_ScreenHeight - vol_Thick - 100
; --------------------
; END OF CONFIGURATION
; --------------------
vol_BarOptionsMaster = 1:B ZH%vol_Thick% ZX8 ZY4 W%vol_Width% X%vol_PosX% Y%vol_PosY% CW%vol_CW%
vol_MuteChange = 0
return


;------------ End if initialization section ----------------

;Exit


$Volume_Down::
#WheelDown::
#-::
  If vol_Master > .01
    VA_SetMasterVolume(vol_Master-=vol_Step)
  Gosub, vol_ShowBars

return

$Volume_Up::
#WheelUp::
#=::
  If vol_Master <= 99
    VA_SetMasterVolume(vol_Master+=vol_Step)
  Gosub, vol_ShowBars

return

Volume_Mute::
#MButton::
#0::
  If ( VA_GetMasterMute() ) {
    VA_SetMasterMute(False)
    vol_MuteChange = 1
  } Else {
    VA_SetMasterMute(True)
    vol_MuteChange = 1
  }
  Gosub, vol_ShowBars

return


#o::
  Send {Media_Stop}
return

#p::
  Send {Media_Play_Pause}
return

#[::
  Send {Media_Prev}
return

#]::
  Send {Media_Next}
return


;  Start Winamp or Open Music Folder
;  Player Window
;  M:\

#\::
Launch_Media::
  IfWinExist Player Window
    IfWinExist M:\
      IfWinActive M:\
        WinClose
      else
        WinActivate
    else
      Run M:\
  else
    Run C:\Program Files (x86)\Winamp\winamp.exe

return

;------------------- Start Volume display ------------------------
vol_ShowBars:
; Get volumes in case the user or an external program changed them:
vol_Master := VA_GetMasterVolume()
vol_Mute := VA_GetMasterMute()
if (vol_Mute)
{
  vol_Colour = Red    
  vol_Text = Volume (muted)
}
else
{
  vol_Colour = Green  
  vol_Text = Volume
}
; To prevent the &quot;flashing&quot; effect, only create the bar window if it doesn't already exist:
NED := 0
IfWinNotExist, VolumeOSDxyz
  NED := 1
If (vol_MuteChange or NED)
{
    Progress, %vol_BarOptionsMaster% CB%vol_Colour% CT%vol_Colour%, , %vol_Text%, VolumeOSDxyz
    WinSet, Transparent, %vol_TransValue%, VolumeOSDxyz
    if (vol_TransBack)
      WinSet, TransColor, %vol_CW%, VolumeOSDxyz

  vol_MuteChange = 0
}
Progress, 1:%vol_Master%, , %vol_Text%
SetTimer, vol_BarOff, %vol_DisplayTime%
return


vol_BarOff:
SetTimer, vol_BarOff, off
Progress, 1:Off
return

;-------------------- End Volume display -------------------------



 

Hey bro, I can't get the win=o,p,[,] to work, could this be due to the fact that I use vlc as media player? also I mod~ the address of winamp on the script to the one where the vlc is, for the win+\, but it's also not required for me since I have vlc on my taskbar and I usually win+number it, but would the script do, if I have a partition set to M: it would open it, instead of opening vlc, right? and I suppose that M:\ is where my music folder would be?

Thanks in advance for your help!

[alaricljs]

I don't recall if it's required to disable the default Win7 win-key combos.  I disabled them quite a while before coming up with this media key layout.  Other than that you have to make sure that whatever media player you are using knows to latch onto the standard media key events.  Never used VLC.

Yes, the 'Launch_Media' is setup to start winamp (you'll have to dig the window details for VLC with Window Spy) if it's not running and to handle the Media Folder if it is running.  My M: drive is a mapping of my server's music storage.  You can change M: to anything you want really, it just needs to be what is in the window title.

[Zet]

Yes, thanks, I got it to lunch VLC instead winamp, which I don't use. Will now try to have it working for my music directory.
By the way I recommend you try VLC, is really good. The only thing I don't like that much is the library management it's easier with other programs.

I'll continue my journeys into the AutoHotKey forums, since I'm really into getting some nice scripts for my keyboard, if I find something awesome, I'll come to share it with you guys here.

[alaricljs]

All my audio management is via the organization of my folders (artist\albums\tracks).  Winamp is just the pretty display and the transport.  I run it window shaded and tuck it down at the bottom, there's a pic in the 'desktop clutter' thread...

Here we go.

[looserboy]

very informative thread, thank you guys for this one, rly, now i could make { and } on my capslock
{ = only press capslock and alt gr + capslock = }

never heard about autohotkey^^ so i am very happy right now

[Zet]

I'm glad this was of help. Perhaps I'll add this to the wiki, make a list of the scripts and such, for others to have a look, and try them in a easy way. We could even upload the compiled versions of the scripts for others to download and use, that way easy.

eh? how do that sounds now?

[litster]

That would be awesome!

[Tony]

I experienced that AHK keyboard scripts won't work if you type fast enough, around 50 wpm.

[daerid]

I experienced that AHK keyboard scripts won't work if you type fast enough, around 50 wpm.

Never had a problem with it, and I type regularly at around 80-90wpm

[Collective]

my script #include(s) chord.ahk, located at http://www.autohotkey.com/forum/topic44399.html
I have it set so that LMB + XButton1 results in sending Alt Space M arrow right, grabbing the window and moving it without needing to hold down a mouse button, and so that LMB + XButton2 results in alt+space , S, down right, which results in grabbing the bottom right corner for resizing without holding down a button.

[Zet]

Hey everyone,

I was enjoying the good life with the volume script that alaricljs posted earlier. I didn't want to update iTunes, but I had to format my computer. So I reinstalled Windows 7, on a new disk I have, and when tried to make the script work... BAM, the forward and backwards song, the win+p for play functions no longer work!

So I thought it was due the fact I installed the wrong version of AHK, or skipped adding the libs VA and COM to the AHK installation place. But I still can't manage to make it work

Can someone advice on this?

Thanks!

[alaricljs]

You mention that you are using iTunes however your earlier post says you got it working with VLC.  So did you later get it working with iTunes prior to this re-install?

The thing to remember about this AHK script and forward/back/play/pause is that all the script does is send a different key press to the OS.  You have to make sure that the OS and/or your media software know that they are what needs to interpret the 'Media Keys', in Winamp this is done with 'Global Hotkeys'.  Just google Media Keys and your software of choice and you should get what you're looking for.

[Zet]

Yes, later on, I stopped using VLC and started using iTunes, as far as I remember, I had installed the last version and was working OK, then re-installed Windows-7 64bits, I took my script(compiled) and the only part working was the volume up, down, mute, and win+\ to open winamp

I'm thinking I did something wrong, when I installed AHK, perhaps the wrong AHK, not _L, maybe I have the wrong libraries installed on a wrong place, or something...

I would really really appreciate if you guide me through this, since I love the script so much I never felt the urge of getting a keyboard with media keys due this.

Thanks in advance alaricljs!

[alaricljs]

For the functions you are saying do not work, all that is happening with the script is that it is taking your key press combination  and translating it to the related media key press that could be found on any keyboard claiming to have media keys.  It is up to iTunes to tell the OS that when media keys are pressed they should be forwarded on to iTunes.  I've never used iTunes so I have zero familiarity with it.  With Winamp it's a specific setting inside the Global Hotkeys screen.  On Windows XP there was a Control Panel that allowed you to fiddle with that stuff as well.  I have not found the same control panel in Win7.

[1uckyNumb3r7]

I have a question for the AHK vets on here....

I am running this line in a script because I am using a Model M and want to have a Windows key for some volume and media function scripts that need that key.

Code: [Select]

RControl::LWin

The key works like it is supposed to, so if I hit RControl+Up then the volume goes up.

My problem is that when I release the RControl after hitting Up then the start menu pops up and I have to hit RControl again in order to make it go away. Is there a way to make it act like a normal LWin key and not pop up on the release of RControl?

[slueth]

i think you can get the windows key by hitting the shift and cntrl or some combo like that.

[1uckyNumb3r7]

i think you can get the windows key by hitting the shift and cntrl or some combo like that.

You might be thinking of Ctrl + Esc? It will bring up the start menu but that is it.

If I were to hit Ctrl+Esc+Up it wouldn't behave the same as Win+Up

Edit: I forgot to mention that if I plug in my other keyboard and try the Win+Up combo the volume goes up and the start menu doesn't pop up.

Edit 2: I found a solution, but it does not involve the use of AutoHotKey unfortunately. http://www.jonlee.ca/remap-capslock-the-most-useless-key/

How to remap Caps Lock to another key
For Linux users (on an X environment like KDE, Gnome), it’s pretty easy to remap keys using the xmodmap command.

For Windows users, there are programs that will remap keys for you but if you’re not afraid to tinker with your registry, you can do this manually and it only requires adding one registry value:

    Go to Start->Run and type in ‘regedit’ to open the registry editor.
    Navigate to:

        HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Keyboard Layout
        Note: Keyboard Layout, not Keyboard Layouts!

    Go to Edit->New->Binary Value and name it ‘Scancode Map’
    Now double-click and edit the value to the following, replacing ## ## with the scan code of the key you wish to map caps lock to.

        00 00 00 00 00 00 00 00 02 00 00 00 ## ## 3a 00 00 00 00 00

    The scan code for Windows Key is 5B E0, Esc is 01 00, Ctrl is 1D 00. Full list of scan codes and a more detailed tutorial is here.
    Reboot your computer and say goodbye to caps lock!

[Hamblet]

...My problem is that when I release the RControl after hitting Up then the start menu pops up and I have to hit RControl again in order to make it go away. Is there a way to make it act like a normal LWin key and not pop up on the release of RControl?

Try this code, It works fine with me (I am AHK_Basic and Vista 32)
Hotkey:: Sendplay {LWin}{Up}

[Shogunner]

Man.. respect you guys.

I've been trying to do a script that does what I want for the past few hours and it's been nothing but frustration. I just ended up using my Belkin n52te to control my media player.

[guilleguillaume]

I ended up using Ripster's code from the first page since mine was causing some problems, very useful.

; Caps Lock becomes Ctrl, Win+LShift becomes Caps Lock
CapsLock::Ctrl
#Lshift::Capslock

Anyone knows how can I learn wich keycode send each key of the keyboard? I want to remap 5 of the Japanese keys I have left that right now don't have any use.

[alaricljs]

PassMark KeyboardTest might be able to pull it off.

[pyro]

Right click on the Autohotkey icon in the notification area
click Open
an Autohotkey window will open, click 'view' >> 'key history and script info' in the menu bar
press any series of keys and then hit F5

[no_mates]

Can some someone please help I need to map the side button (#7) on my CM Spawn to the shift key for BF3.  There appears to be a bug with the Spawn where some modifier keys don't work even though the software say's they're mapped?